[TUTORIEL] Module Peltier

Informations et questions sur les composants tiers de la boutique (émetteur/récepteur RF, capteurs...)

[TUTORIEL] Module Peltier

Message non lude Florian » Jeu 6 Mar 2014 18:24

Bonjour,

Aujourd'hui nous allons à la découverte du module Peltier.

Module_Peltier.jpg
Module_Peltier.jpg (13.12 Kio) Vu 2251 fois


Le module Peltier comme son nom l'indique fonctionne grâce à l'effet Peltier.
L'effet Peltier (aussi appelé effet thermoélectrique) est un phénomène physique de déplacement de chaleur en présence d'un courant électrique. L'effet se produit dans des matériaux conducteurs de natures différentes liés par des jonctions (contacts). L'une des jonctions se refroidit alors légèrement, pendant que l'autre se réchauffe. Cet effet a été découvert en 1834 par le physicien Jean-Charles Peltier.


En simple, à partir d'un courant électrique un des côtés du module va absorber la chaleur (donc se refroidir) et l'autre va dissiper cette chaleur (donc chauffer). On peut également produire le phénomène réciproque qui est l'effet Seebeck.
L'usage le plus connu du module Peltier est la glacière qu'on branche sur l'allume-cigare de notre voiture quand on part en vacances.

Pour plus de détails sur le fonctionnement de l'effet Peltier, vous pouvez aller sur Wikipedia.
Produit disponible ici, Snootlab.


EXEMPLE D'UTILISATION

Le montage que nous allons réaliser va faire chauffer/refroidir le module Peltier dès que nous approcherons notre main ou un objet d'un capteur de distance. Plus l'objet ou votre main sera proche du capteur plus le module va chauffer/refroidir. Et inversement, plus ce sera éloigné moins le module chauffera/refroidira jusqu'à ne plus chauffer du tout ni refroidir.

Préambule:
[TUTORIEL] Module à ultrasons HC-SR04.
Petit tutoriel sur l'utilisation du capteur HC-SR04 que nous allons utiliser dans notre montage.

- MATÉRIEL:


- SCHÉMA DU MONTAGE:
Montage_Peltier_Capteur.PNG
Montage_Peltier_Capteur.PNG (73.8 Kio) Vu 2251 fois


Alimentation du montage:
- Le module Peltier présenté peut aller jusqu'à une tension de 15,4 V et un courant de 7 A. Donc si vous voulez réellement que votre module produise du froid (ou du chaud), il vaut mieux le brancher à une source externe plus puissante que ce que peut fournir la carte Uno. Ou faire comme dans le montage ci-dessus, c'est à dire le relier à Vin et utiliser le jack de l'Arduino pour apporter une source suffisamment puissante. Personnellement, j'utilise une alimentation qui fournit du 9 V en continu pour du 1 A et le résultat est plus que satisfaisant.
- Vous pouvez remarquer que le capteur de distance n'est pas relié au Vin. En effet, ce composant fonctionne sous une tension de 5 V en continue donc celle de Vin est trop élevée pour l'utiliser.

Le transistor:
A quoi sert le transistor de puissance? En réalité, c'est lui qui alimente le module Peltier. Nous avons expliqué au début du tutoriel que nous voulions que notre module chauffe plus ou moins en fonction de la distance qui sépare notre main/objet du capteur. Plus nous sommes près du capteur plus il produit du froid et inversement. Pour arriver à faire ceci nous devons pouvoir contrôler la puissance qui sera délivrée au Peltier. Donc nous devons faire de la PWM.
Pour cela nous avons besoin de ce transistor. Il fournit la puissance nécessaire au module. Donc en contrôlant la puissance de ce dernier par PWM, on peut contrôler la puissance donnée au module Peltier. Donc gérer sa capacité à chauffer/produire du froid plus ou moins fort.

Branchement:
    ==> Concernant le capteur:
    - Vcc du capteur au 5 V de l'Arduino.
    - GND au GND.
    - Trig du capteur à la pin 3 de l'Arduino.
    - Echo du capteur à la pin 2 de l'Arduino.

    ==> Concernant le Transistor:
    - Pin 1 du transistor à la pin 11 de l'Arduino et au GND.
    - Pin 2 du transistor au câble noir du module Peltier.
    - Pin 3 du transistor au GND.

    ==> Concernant le module Peltier:
    - Câble noir du module au GND.
    - Câble rouge au Vin de l'Arduino Uno.

Voilà pour les explications de la partie Hardware.

- CODE:
Code: Tout sélectionner
    /*
        Sketch mettant en œuvre un module Peltier avec un capteur de distance.
        Plus la distance diminue avec le capteur, plus le Peltier va chauffer/refroidir.
        La puissance du Peltier est régulée en PWM par un transistor NPN
    */


    #include <NewPing.h>  // Inclus la librairie NewPing pour le capteur HC-SR04.

    int Echo = 2;  // Pin "Echo" du HC-SR04, connectée à la Pin 2 de l'Arduino.
    int Trig = 3;  // Pin "Trig" du HC-SR04, connectée à la Pin 3 de l'Arduino.
    int DistanceMax = 100;  // Distance maximum souhaitée (en centimètres). Le capteur peut aller jusqu'à une distance de 400-500cm.

    NewPing sonar (Trig, Echo, DistanceMax);  // Paramétrage des Pins et de la distance max pour le ping.

    int Peltier = 11;  // transistor NPN , connecté à la Pin 11 de l'Arduino.

    int Puissance;  // Pourcentage puissance allant de 0 à 100.
    int NiveauPWM = map(Puissance, 0, 100, 0, 255);  // Valeur réelle allant de 0 à 255 qui contrôle le transistor.



    void setup()
    {
      pinMode(Peltier, OUTPUT);  // Programme la Pin connectée au Peltier en sortie.
      Serial.begin(9600);  // Démarre et fixe le débit de communication.
    }



    void loop()
    {
      delay(50);  // Attend 50ms entre deux pings (soit autour de 20 pings/s). Le delay peut être raccourci jusqu'à 29ms entre chaque pings.
      unsigned int uS = sonar.ping();  // Envoi d'un ping, interprète en microseconde (uS).
      Serial.print("Distance: ");
      Serial.print(uS / US_ROUNDTRIP_CM);  // Conversion en cm.
      Serial.println("cm");
     
      if((uS / US_ROUNDTRIP_CM)==0)  // Boucle if, condition.
      {
        Puissance = 0;  // Si la distance égale 0 alors la puissance égale 0.
      }
      else
      {
        Puissance = 100 - (uS / US_ROUNDTRIP_CM);  // Autrement Puissance = 100 - Distance.
      }
     
      NiveauPWM = map(Puissance, 0, 100, 0, 255);  // Calcul proportionnel du pourcentage de la puissance en PWM.
     
      Serial.print("Puissance = ");  // Moniteur série affiche le pourcentage de puissance fournie au module Peltier.
      Serial.print(Puissance);
      Serial.print(" %");
      Serial.print(" ==> PWM = ");  // Moniteur série affiche la PWM équivalente au pourcentage de puissance fournie au module Peltier.
      Serial.print(NiveauPWM);
      Serial.println(".");
     
      delay(2000);  // Affiche les données toutes les deux secondes sur le moniteur série.
     
      analogWrite(Peltier, NiveauPWM);  // Envoi de la nouvelle valeur.
    }


Pour la partie Soft.
Avant toute chose pour pouvoir utiliser le sketch précédent, il vous faudra installer la librairie "NewPing". C'est cette librairie qui va permettre au capteur HC-SR04 de pouvoir calculer la distance qui le sépare de l'objet. Ce capteur fonctionne par ultrasons. Il envoie un "ping" (une onde) d'une certaine célérité et calcule la distance que le "ping" a parcourue en fonction du temps qu'il a mis à parcourir cette distance.
Librairie "NewPing".

Dans la partie déclaration du programme, vous devriez normalement trouver ces deux lignes;
Code: Tout sélectionner
int Echo = 2;  // Pin "Echo" du HC-SR04, connectée à la Pin 2 de l'Arduino.
int Trig = 3;  // Pin "Trig" du HC-SR04, connectée à la Pin 3 de l'Arduino.
int DistanceMax = 100;  // Distance maximum souhaitée (en centimètres). Le capteur peut aller jusqu'à une distance de 400-500 cm.

NewPing sonar (Trig, Echo, DistanceMax);  // Paramétrage des Pins et de la distance max pour le ping.

Les deux premières définissent les pins utilisées sur l'Arduino.
La troisième ligne permet de définir la distance maximum que vous souhaitez voir mesurée par votre capteur. Il faut savoir que le capteur HC-SR04 peut mesurer une distance maximum allant de 4 à 5 mètres. Il faut rentrer la distance désirée en centimètres. Il faut également savoir que lorsque le capteur ne détecte rien dans sa zone de mesure, il affiche une distance de zéro centimètre. Autrement dit, si vous réglez sa zone de mesure à 2 mètres et que l'objet se trouve à une distance de 2,17 mètres alors le capteur vous donnera 0 cm comme résultat de mesure.
La dernière ligne initialise et programme les paramètres rentrés juste avant.

Dans le sketch, la distance maximum définie est d'un mètre. Pour faire correspondre la distance à un pourcentage de puissance, on peut utiliser le calcul suivant "Puissance = 100 - Distance". Admettons que la distance mesurée par le capteur est de 45 cm. De part ce calcul, on aura une puissance utilisée égale à 55%.
Ensuite, il suffit d'incorporer ceci dans une boucle "if" pour régler le problème d'une distance égale à 0 si rien ne se trouve dans le champ de mesure du capteur. En effet, si rien n'est mesuré, il affiche 0 cm et nous aurons donc une puissance égale à 100% alors que rien ne serait devant le capteur. La boucle "if" permet de dire si distance = 0 alors puissance = 0. Autrement "Puissance = 100 - Distance".

Dans la boucle "loop" du programme, vous devriez voir cette ligne;
Code: Tout sélectionner
NiveauPWM = map(Puissance, 0, 100, 0, 255);  // Calcul proportionnel du pourcentage de la puissance en PWM.

Cette ligne fait correspondre de façon proportionnelle le pourcentage de puissance (de 0 à 100) à un niveau de PWM (de 0 à 255) qui sera délivrée au module Peltier.


- MONITEUR SÉRIE:
Une fois les branchements et le montage correctement effectués, la librairie "NewPing" correctement installée et le sketch uploadé sur votre Arduino. Ouvrez votre moniteur série. Vous devriez obtenir quelque chose de semblable à ceci;
Moniteur-Peltier.PNG
Moniteur-Peltier.PNG (28.79 Kio) Vu 2251 fois


On remarque que le moniteur affiche zéro cm lorsque rien n'est détecté dans son champ d'action. Et donc puissance à zéro et PWM à zéro. A partir du moment où un objet rentre dans le champ d'action, on voit bien que dès que la distance entre l'objet et le capteur diminue le pourcentage de puissance augmente. Et donc la PWM augmente aussi de manière proportionnelle par rapport au pourcentage de puissance. Et inversement quand l'objet s'éloigne du capteur.
Normalement si tout fonctionne correctement, plus vous diminuez la distance entre votre objet et votre capteur plus l'une des faces du module Peltier devrait se refroidir et l'autre chauffer et inversement.



Et voilà, vous savez utiliser un module Peltier. Maintenant à vous d'imaginer d'autres montages que ce soit pour vos projets ou simplement pour le fun.
Vous pouvez par exemple réaliser un petit montage où l'on poserait un verre de whisky sur la face froide du Peltier pour pouvoir refroidir ce divin nectar sans le dénaturer en le diluant avec des glaçons. Tout en adaptant la température (en gérant la puissance du module) en fonction de la quantité de liquide présent de le verre par exemple.



Voilà, voilà! C'est tout pour aujourd'hui, en espérant que ça vous ait plu.
Florian
 
Messages: 70
Inscription: Mer 24 Juil 2013 17:36

Retourner vers Composants tiers

Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 1 invité

cron