Interactions Akeru / GPS Ultimate

Forum de support et d'échange sur la carte Akeru (carte compatible Arduino développée par Snootlab et intégrant la technologie Sigfox) et du shield Akene pour Arduino (shield pour Arduino développée par Snootlab et intégrant la technologie Sigfox)

Interactions Akeru / GPS Ultimate

Message non lude FPierre » Jeu 25 Juin 2015 08:16

Bonjour tout le monde,

Je suis en train de faire un GPS connecté à une Akeru Beta 3.3. Je rencontre pas mal de problèmes sur les interactions entre ces 2 parties. Plus en détail :

- GPS : https://learn.adafruit.com/adafruit-ultimate-gps. Branché sans utiliser Sigfox, je reçois bien les infos GPS

- Carte Akeru http://snootlab.com/lang-en/snootlab-shields/829-akeru-beta-33-en.html. Sans utiliser le GPS, j'envoi bien des données (réception sur Actoboard)

Quand j'essaye de faire fonctionner les 2 (envoi de coordonnées GPS à Sigfox), rien ne marche : la carte reste bloquée sur l'étape
Code: Tout sélectionner
isReady();
.

J'ai essayé pas mal de codes, de tutos, de techniques, rien de fonctionne, toujours ce isReady qui ne passe pas...

Exemple de codes testés (en tout j'en ai testé un 20aines, aucun ne fonctionne) :

- https://github.com/Ekito/hackerz_akeru

- https://github.com/joshfire/akeru_gps

- https://github.com/nicolsc/akeru-first-message


Quelqu'un a t'il déjà eu ce cas d'incompatibilité ? Est-ce que ça peut être lié aux ports 4 et 5 réservés sur l'Akeru ?
Toutes infos sont bonnes à prendre, je suis vraiment bloqué.

Si vous avez besoin de plus de détails, demandez, je donne ;)


Merci !
FPierre
 
Messages: 1
Inscription: Mer 24 Juin 2015 09:10

Re: Interactions Akeru / GPS Ultimate

Message non lude Laetitia » Lun 29 Juin 2015 11:14

Bonjour,

Où avez-vous branché le module GPS ? Les broches 4 et 5 de l'Akeru sont en effet utilisées, donc à laisser libres.
"If it's itchy, scratch it !" - "DIY or die"

RTFM (À lire avant de poster) - ANDb (Arduino Noob Database)
Avatar de l’utilisateur
Laetitia
 
Messages: 286
Inscription: Mar 7 Aoû 2012 15:07
Localisation: Toulouse

Re: Interactions Akeru / GPS Ultimate

Message non lude fred » Lun 29 Juin 2015 15:06

Essayer 50 codes ne servira à rien si la phase algorithmique n'est pas maîtrisée.

Postez le code le plus propre et maîtrisé que vous avez ainsi que le schéma de câblage (en vérifiant fil par fil et signal par signal) que ce que vous avec schématisé est ce que vous avez câblé (on a parfois des surprises).

Vous pouvez aussi poster des photos.

Cordialement.
Avatar de l’utilisateur
fred
 
Messages: 213
Inscription: Lun 20 Déc 2010 15:32
Localisation: Toulouse

Re: Interactions Akeru / GPS Ultimate

Message non lude nicosan » Jeu 11 Fév 2016 23:24

Bonjour,

je rencontre le même problème que celui mentionné dans ce sujet - à ceci près que j'utilise un shield Akene.

J'ai stacké les shields sur mon Arduino Uno (uniquement ces deux-là).

Réception GPS seule (9600 bauds, pin 8 Rx 7 Tx) : Ok
Envoi de données Sigfox seul (pin 4 et 5) : Ok

Quand je combien l'utilisation des deux shields, je reste aussi bloqué sur l'étape Akeru.isReady().

Pouvez-vous SVP m'apporter des pistes afin de résoudre ce problème ?

Merci,
Nicolas
Dernière édition par nicosan le Lun 15 Fév 2016 14:30, édité 1 fois.
nicosan
 
Messages: 5
Inscription: Jeu 11 Fév 2016 23:13

Re: Interactions Akeru / GPS Ultimate

Message non lude Laetitia » Ven 12 Fév 2016 10:32

Bonjour,

Mêmes remarques que précédemment, merci de poster les schémas et codes utilisés.

Note : le post d'origine utilisait un breakout Ultimate GPS, et non un shield (il existe cependant chez Adafruit un Ultimate GPS Logger Shield). Parle-t-on bien du même matériel ?

Consultez ce post pour plus de détails sur la fonction Akeru.isReady().
"If it's itchy, scratch it !" - "DIY or die"

RTFM (À lire avant de poster) - ANDb (Arduino Noob Database)
Avatar de l’utilisateur
Laetitia
 
Messages: 286
Inscription: Mar 7 Aoû 2012 15:07
Localisation: Toulouse

Re: Interactions Akeru / GPS Ultimate

Message non lude nicosan » Ven 12 Fév 2016 11:16

Bjr,

oui je parle bien ici du Ultimate GPS Logger Shield.

Je précise que j'avais bien noté le fonctionnement de la fonction Akeru.isReady(). Pour préciser mon problème (il était tard hier soir !) : il s'agit plus d'une interférence de l'activation du modem sur le fonctionnement du GPS.

Photos du montage :
https://www.dropbox.com/s/tyxp40sqvd74z ... 8.jpg?dl=0
https://www.dropbox.com/s/ajr4lqp1lyw8z ... 7.jpg?dl=0

Pour le code j'ai pas osé désolé après avoir lu ça :shock: :? "Essayer 50 codes ne servira à rien si la phase algorithmique n'est pas maîtrisée."

Néanmoins le voici :
Code: Tout sélectionner
// Test code for Adafruit GPS modules using MTK3329/MTK3339 driver
//
// This code shows how to listen to the GPS module in an interrupt
// which allows the program to have more 'freedom' - just parse
// when a new NMEA sentence is available! Then access data when
// desired.
//
// Tested and works great with the Adafruit Ultimate GPS module
// using MTK33x9 chipset
//    ------> http://www.adafruit.com/products/746
// Pick one up today at the Adafruit electronics shop
// and help support open source hardware & software! -ada

#include <Adafruit_GPS.h>
#include <SoftwareSerial.h>
#include <Akeru.h>


// If you're using a GPS module:
// Connect the GPS Power pin to 5V
// Connect the GPS Ground pin to ground
// If using software serial (sketch example default):
//   Connect the GPS TX (transmit) pin to Digital 3
//   Connect the GPS RX (receive) pin to Digital 2
// If using hardware serial (e.g. Arduino Mega):
//   Connect the GPS TX (transmit) pin to Arduino RX1, RX2 or RX3
//   Connect the GPS RX (receive) pin to matching TX1, TX2 or TX3

// If you're using the Adafruit GPS shield, change
// SoftwareSerial mySerial(3, 2); -> SoftwareSerial mySerial(8, 7);
// and make sure the switch is set to SoftSerial

// If using software serial, keep this line enabled
// (you can change the pin numbers to match your wiring):
SoftwareSerial mySerial(8, 7);

// If using hardware serial (e.g. Arduino Mega), comment out the
// above SoftwareSerial line, and enable this line instead
// (you can change the Serial number to match your wiring):

//HardwareSerial mySerial = Serial1;


Adafruit_GPS GPS(&mySerial);


// Set GPSECHO to 'false' to turn off echoing the GPS data to the Serial console
// Set to 'true' if you want to debug and listen to the raw GPS sentences.
#define GPSECHO  true

// this keeps track of whether we're using the interrupt
// off by default!
boolean usingInterrupt = true;
void useInterrupt(boolean); // Func prototype keeps Arduino 0023 happy

void setup() 
{
   
  // connect at 115200 so we can read the GPS fast enough and echo without dropping chars
  // also spit it out
  Serial.begin(115200);
  Serial.println("Adafruit GPS library basic test!");

  // 9600 NMEA is the default baud rate for Adafruit MTK GPS's- some use 4800
  GPS.begin(9600);
 
  // uncomment this line to turn on RMC (recommended minimum) and GGA (fix data) including altitude
  GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCGGA);
  // uncomment this line to turn on only the "minimum recommended" data
  //GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCONLY);
  // For parsing data, we don't suggest using anything but either RMC only or RMC+GGA since
  // the parser doesn't care about other sentences at this time
 
  // Set the update rate
  GPS.sendCommand(PMTK_SET_NMEA_UPDATE_1HZ);   // 1 Hz update rate
  // For the parsing code to work nicely and have time to sort thru the data, and
  // print it out we don't suggest using anything higher than 1 Hz

  // Request updates on antenna status, comment out to keep quiet
  GPS.sendCommand(PGCMD_ANTENNA);

  // the nice thing about this code is you can have a timer0 interrupt go off
  // every 1 millisecond, and read data from the GPS for you. that makes the
  // loop code a heck of a lot easier!
  useInterrupt(true);

  delay(1000);
  // Ask for firmware version
  mySerial.println(PMTK_Q_RELEASE);

[b]  // Init modem
  Akeru.begin();[/b]
}


// Interrupt is called once a millisecond, looks for any new GPS data, and stores it
SIGNAL(TIMER0_COMPA_vect) {
  char c = GPS.read();
  // if you want to debug, this is a good time to do it!
#ifdef UDR0
  if (GPSECHO)
    if (c) UDR0 = c; 
    // writing direct to UDR0 is much much faster than Serial.print
    // but only one character can be written at a time.
#endif
}

void useInterrupt(boolean v) {
  if (v) {
    // Timer0 is already used for millis() - we'll just interrupt somewhere
    // in the middle and call the "Compare A" function above
    OCR0A = 0xAF;
    TIMSK0 |= _BV(OCIE0A);
    usingInterrupt = true;
  } else {
    // do not call the interrupt function COMPA anymore
    TIMSK0 &= ~_BV(OCIE0A);
    usingInterrupt = false;
  }
}

uint32_t timer = millis();
void loop()                     // run over and over again
{
  // in case you are not using the interrupt above, you'll
  // need to 'hand query' the GPS, not suggested :(
  if (! usingInterrupt) {
    // read data from the GPS in the 'main loop'
    char c = GPS.read();
    // if you want to debug, this is a good time to do it!
    if (GPSECHO)
      if (c) Serial.print(c);
  }
 
  // if a sentence is received, we can check the checksum, parse it...
  if (GPS.newNMEAreceived()) {
    // a tricky thing here is if we print the NMEA sentence, or data
    // we end up not listening and catching other sentences!
    // so be very wary if using OUTPUT_ALLDATA and trytng to print out data
    //Serial.println(GPS.lastNMEA());   // this also sets the newNMEAreceived() flag to false
 
    if (!GPS.parse(GPS.lastNMEA()))   // this also sets the newNMEAreceived() flag to false
      return;  // we can fail to parse a sentence in which case we should just wait for another
  }

  // if millis() or timer wraps around, we'll just reset it
  if (timer > millis())  timer = millis();

  // approximately every 2 seconds or so, print out the current stats
  if (millis() - timer > 2000) {
    timer = millis(); // reset the timer
   
    Serial.print("\nTime: ");
    Serial.print(GPS.hour, DEC); Serial.print(':');
    Serial.print(GPS.minute, DEC); Serial.print(':');
    Serial.print(GPS.seconds, DEC); Serial.print('.');
    Serial.println(GPS.milliseconds);
    Serial.print("Date: ");
    Serial.print(GPS.day, DEC); Serial.print('/');
    Serial.print(GPS.month, DEC); Serial.print("/20");
    Serial.println(GPS.year, DEC);
    Serial.print("Fix: "); Serial.print((int)GPS.fix);
    Serial.print(" quality: "); Serial.println((int)GPS.fixquality);
    if (GPS.fix) {
      Serial.print("Location: ");
      Serial.print(GPS.latitude, 4); Serial.print(GPS.lat);
      Serial.print(", ");
      Serial.print(GPS.longitude, 4); Serial.println(GPS.lon);
      Serial.print("Location (in degrees, works with Google Maps): ");
      Serial.print(GPS.latitudeDegrees, 4);
      Serial.print(", ");
      Serial.println(GPS.longitudeDegrees, 4);
     
      Serial.print("Speed (knots): "); Serial.println(GPS.speed);
      Serial.print("Angle: "); Serial.println(GPS.angle);
      Serial.print("Altitude: "); Serial.println(GPS.altitude);
      Serial.print("Satellites: "); Serial.println((int)GPS.satellites);
    }
  }
}


Après avoir exposé mon problème hier je suis reparti d'une situation maîtrisée : l'exemple 'parsing' fourni avec la librairie du GPS fonctionne parfaitement :
Code: Tout sélectionner
Time: 10:4:46.0
Date: 12/2/2016
Fix: 1 quality: 1
Location: 4929.8076N, 603.0389E
Location (in degrees, works with Google Maps): 49.4968, 6.0506
Speed (knots): 0.50
Angle: 81.37
Altitude: 295.20
Satellites: 4
$PGTOP,11,2*6E
$GPGGA,100447.000,4929.8073,N,00603.0388,E,1,04,2.85,295.2,M,47.7,M,,*65
$GPRMC,100447.000,A,4929.8073,N,00603.0388,E,0.29,69.87,120216,,,A*59
$PGTOP,11,2*6E
$GPGGA,100448.000,4929.8075,N,00603.0392,E,1,04,2.85,295.2,M,47.7,M,,*67
$GPRMC,100448.000,A,4929.8075,N,00603.0392,E,0.46,66.04,120216,,,A*56


Mais dès que j'ajoute dans la fonction de setup() (à la fin, voir code plus haut) l'initialisation du modem :
Code: Tout sélectionner
  // Init modem
  Akeru.begin();

je ne parviens plus à récupérer de coordonnées GPS. Je précise qu'aucune condition/réglage/etc n'a changé entre temps :
Code: Tout sélectionner
Time: 0:0:0.0
Date: 0/0/200
Fix: 0 quality: 0


J'ai essayé de démarrer le GPS sur 4800 bauds mais même résultat.

Merci pour votre aide.
nicosan
 
Messages: 5
Inscription: Jeu 11 Fév 2016 23:13

Re: Interactions Akeru / GPS Ultimate

Message non lude nicosan » Dim 14 Fév 2016 23:15

Bonjour,
Le branchement vous paraît-il bon ? Souhaitez-vous plus de détails à son sujet ?
Avez-vous un retour d'expérience quelconque concernant l'utilisation conjointe de ces deux
Merci pour votre aide
nicosan
 
Messages: 5
Inscription: Jeu 11 Fév 2016 23:13

Re: Interactions Akeru / GPS Ultimate

Message non lude Laetitia » Lun 15 Fév 2016 12:06

Bonjour,

Rien à redire sur les branchements (l'avantage des shields c'est que l'on a pas à se préoccuper des câbles à mettre au bon endroit).
Aucun retour d'expérience pour le moment sur cette configuration, donc je suis en train de la tester moi-même.

J'arrive effectivement à reproduire le bug mais pour le moment je ne saurais dire d'où il vient.
Je continue d'investiguer et je reviens vers vous !
"If it's itchy, scratch it !" - "DIY or die"

RTFM (À lire avant de poster) - ANDb (Arduino Noob Database)
Avatar de l’utilisateur
Laetitia
 
Messages: 286
Inscription: Mar 7 Aoû 2012 15:07
Localisation: Toulouse

Re: Interactions Akeru / GPS Ultimate

Message non lude nicosan » Lun 15 Fév 2016 12:13

Merci pour votre réactivité !
De mon côté je vous avoue avoir laissé ça de côté ; mais je n'hésiterai pas à vous faire signe si je venais à identifier de nouveaux comportements.
nicosan
 
Messages: 5
Inscription: Jeu 11 Fév 2016 23:13

Re: Interactions Akeru / GPS Ultimate

Message non lude Laetitia » Mar 16 Fév 2016 16:09

Bonjour,

La librairie softwareSerial exploitée par les librairies Akeru et Adafruit_GPS impose une restriction lorsque l'on manipule plusieurs ports : il faut arrêter de parler à l'un pour pouvoir commencer une conversation avec un autre !

Pour y remédier, il faut ajouter dans le fichier Akeru.h, dans les méthodes publiques :

Code: Tout sélectionner
void listen();

Puis dans Akeru.cpp :

Code: Tout sélectionner
void Akeru_::listen()
{
  _serial.listen();
}

La liaison softwareSerial utilisée par le GPS est accessible depuis le sketch donc on exploitera la fonction listen() associée directement, ça nous évitera d'avoir à modifier la librairie Adafruit_GPS.

Autre détail : l'appel de la fonction Akeru.isReady() à chaque tour de loop() comme dans l'exemple akeru_test_analog0 peut bloquer la réception des trames NMEA (il faut leur laisser le temps d'arriver), pour contourner le problème on insère un délai façon BlinkWithoutDelay, similaire à celui présent en début de loop.

La fonction Akeru.isReady() est appelée lors de chaque Akeru.send(), et empêchera l'envoi du message si elle retourne 0, en fait utiliser les deux consécutivement fait un peu bretelles + ceinture :roll:

Le code complet, corrigé, testé :

Code: Tout sélectionner
// Test code for Adafruit GPS modules using MTK3329/MTK3339 driver
//
// This code shows how to listen to the GPS module in an interrupt
// which allows the program to have more 'freedom' - just parse
// when a new NMEA sentence is available! Then access data when
// desired.
//
// Tested and works great with the Adafruit Ultimate GPS module
// using MTK33x9 chipset
//    ------> http://www.adafruit.com/products/746
// Pick one up today at the Adafruit electronics shop
// and help support open source hardware & software! -ada

#include <Adafruit_GPS.h>
#include <SoftwareSerial.h>
#include <Akeru.h>


// If you're using a GPS module:
// Connect the GPS Power pin to 5V
// Connect the GPS Ground pin to ground
// If using software serial (sketch example default):
//   Connect the GPS TX (transmit) pin to Digital 3
//   Connect the GPS RX (receive) pin to Digital 2
// If using hardware serial (e.g. Arduino Mega):
//   Connect the GPS TX (transmit) pin to Arduino RX1, RX2 or RX3
//   Connect the GPS RX (receive) pin to matching TX1, TX2 or TX3

// If you're using the Adafruit GPS shield, change
// SoftwareSerial mySerial(3, 2); -> SoftwareSerial mySerial(8, 7);
// and make sure the switch is set to SoftSerial

// If using software serial, keep this line enabled
// (you can change the pin numbers to match your wiring):
SoftwareSerial mySerial(8, 7);

// If using hardware serial (e.g. Arduino Mega), comment out the
// above SoftwareSerial line, and enable this line instead
// (you can change the Serial number to match your wiring):

//HardwareSerial mySerial = Serial1;


Adafruit_GPS GPS(&mySerial);


// Set GPSECHO to 'false' to turn off echoing the GPS data to the Serial console
// Set to 'true' if you want to debug and listen to the raw GPS sentences.
#define GPSECHO  true

// this keeps track of whether we're using the interrupt
// off by default!
boolean usingInterrupt = true;
void useInterrupt(boolean); // Func prototype keeps Arduino 0023 happy

void setup()
{
   
  // connect at 115200 so we can read the GPS fast enough and echo without dropping chars
  // also spit it out
  Serial.begin(115200);
  Serial.println("Adafruit GPS library basic test!");

  // 9600 NMEA is the default baud rate for Adafruit MTK GPS's- some use 4800
  GPS.begin(9600);
 
  // uncomment this line to turn on RMC (recommended minimum) and GGA (fix data) including altitude
  GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCGGA);
  // uncomment this line to turn on only the "minimum recommended" data
  //GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCONLY);
  // For parsing data, we don't suggest using anything but either RMC only or RMC+GGA since
  // the parser doesn't care about other sentences at this time
 
  // Set the update rate
  GPS.sendCommand(PMTK_SET_NMEA_UPDATE_1HZ);   // 1 Hz update rate
  // For the parsing code to work nicely and have time to sort thru the data, and
  // print it out we don't suggest using anything higher than 1 Hz

  // Request updates on antenna status, comment out to keep quiet
  GPS.sendCommand(PGCMD_ANTENNA);

  // the nice thing about this code is you can have a timer0 interrupt go off
  // every 1 millisecond, and read data from the GPS for you. that makes the
  // loop code a heck of a lot easier!
  useInterrupt(true);

  delay(1000);
  // Ask for firmware version
  mySerial.println(PMTK_Q_RELEASE);

  // Init modem
  Akeru.begin();
}


// Interrupt is called once a millisecond, looks for any new GPS data, and stores it
SIGNAL(TIMER0_COMPA_vect) {
  char c = GPS.read();
  // if you want to debug, this is a good time to do it!
#ifdef UDR0
  if (GPSECHO)
    if (c) UDR0 = c;
    // writing direct to UDR0 is much much faster than Serial.print
    // but only one character can be written at a time.
#endif
}

void useInterrupt(boolean v) {
  if (v) {
    // Timer0 is already used for millis() - we'll just interrupt somewhere
    // in the middle and call the "Compare A" function above
    OCR0A = 0xAF;
    TIMSK0 |= _BV(OCIE0A);
    usingInterrupt = true;
  } else {
    // do not call the interrupt function COMPA anymore
    TIMSK0 &= ~_BV(OCIE0A);
    usingInterrupt = false;
  }
}

uint32_t timer = 0;       // dernière impression données GPS
unsigned long timer2 = 0; // dernier envoi Sigfox

void loop()                     // run over and over again
{
  mySerial.listen();
 
  // in case you are not using the interrupt above, you'll
  // need to 'hand query' the GPS, not suggested :(
  if (! usingInterrupt) {
    // read data from the GPS in the 'main loop'
    char c = GPS.read();
    // if you want to debug, this is a good time to do it!
    if (GPSECHO)
      if (c) Serial.print(c);
  }
 
  // if a sentence is received, we can check the checksum, parse it...
  if (GPS.newNMEAreceived()) {
    // a tricky thing here is if we print the NMEA sentence, or data
    // we end up not listening and catching other sentences!
    // so be very wary if using OUTPUT_ALLDATA and trytng to print out data
    //Serial.println(GPS.lastNMEA());   // this also sets the newNMEAreceived() flag to false
 
    if (!GPS.parse(GPS.lastNMEA()))   // this also sets the newNMEAreceived() flag to false
      return;  // we can fail to parse a sentence in which case we should just wait for another
  }

  // if millis() or timer wraps around, we'll just reset it
  if (timer > millis())  timer = millis();

  // approximately every 2 seconds or so, print out the current stats
  if (millis() - timer > 2000) {
    timer = millis(); // reset the timer
   
    Serial.print("\nTime: ");
    Serial.print(GPS.hour, DEC); Serial.print(':');
    Serial.print(GPS.minute, DEC); Serial.print(':');
    Serial.print(GPS.seconds, DEC); Serial.print('.');
    Serial.println(GPS.milliseconds);
    Serial.print("Date: ");
    Serial.print(GPS.day, DEC); Serial.print('/');
    Serial.print(GPS.month, DEC); Serial.print("/20");
    Serial.println(GPS.year, DEC);
    Serial.print("Fix: "); Serial.print((int)GPS.fix);
    Serial.print(" quality: "); Serial.println((int)GPS.fixquality);
    if (GPS.fix) {
      Serial.print("Location: ");
      Serial.print(GPS.latitude, 4); Serial.print(GPS.lat);
      Serial.print(", ");
      Serial.print(GPS.longitude, 4); Serial.println(GPS.lon);
      Serial.print("Location (in degrees, works with Google Maps): ");
      Serial.print(GPS.latitudeDegrees, 4);
      Serial.print(", ");
      Serial.println(GPS.longitudeDegrees, 4);
     
      Serial.print("Speed (knots): "); Serial.println(GPS.speed);
      Serial.print("Angle: "); Serial.println(GPS.angle);
      Serial.print("Altitude: "); Serial.println(GPS.altitude);
      Serial.print("Satellites: "); Serial.println((int)GPS.satellites);
    }
  }

  if (timer2 > millis()) timer2 = millis(); // reset si overflow
 
  if (millis() - timer2 > 600000) // 10 minutes entre chaque envoi
  {
    timer2 = millis();
   
    Akeru.listen(); // softwareSerial : désactivation GPS, activation TD1208
   
    Serial.println("\nSending data...");
    int data = analogRead(0); // à remplacer par les données de votre choix
    Akeru.send(&data, sizeof(data));
   
    mySerial.listen(); // softwareSerial : désactivation TD1208, activation GPS
  }
}

Cette manip est valable pour tous les modules/shields exploitant une liaison SoftwareSerial, merci pour le feedback, c'est pris en compte et ajouté dans la librairie ! Nouvelle version dispo sur Github.
"If it's itchy, scratch it !" - "DIY or die"

RTFM (À lire avant de poster) - ANDb (Arduino Noob Database)
Avatar de l’utilisateur
Laetitia
 
Messages: 286
Inscription: Mar 7 Aoû 2012 15:07
Localisation: Toulouse

Re: Interactions Akeru / GPS Ultimate

Message non lude nicosan » Jeu 18 Fév 2016 13:40

Parfait ! tout fonctionne à merveille maintenant.

Merci beaucoup pour votre aide et votre réactivité.
nicosan
 
Messages: 5
Inscription: Jeu 11 Fév 2016 23:13


Retourner vers Akeru et Akene

Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 2 invités